1 [2] MLD-6.x / General / Entwicklungsumgebung 6.5
 

Offline clausmuus

  • Administrator
  • Expert Member
  • ********
  • Posts: 21280
    • View Profile
    • ClausMuus.de
Entwicklungsumgebung 6.5
« Reply #15 on: February 15, 2026, 08:38:23 »
Beim dvd Plugin sollte sich das Device per -C Parameter ändern lassen. Das habe ich in den Sourcen überprüft.
Du kannst ja mal checken ob im Log die Meldung "vdr: DVD drive not found" auftaucht. Es wird bei starten geprüft ob das Device existiert.
Der Ordner /dev wird bei jedem booten neu erstellt (das ist kein normaler Ordner). Um das device /dev/dvd dauerhaft zu erstellen, musst Du eine udev Regel erstellen, die dieses anlegt, sobald ein dvd Laufwerk auftaucht.
Logged
MLD 5.5 - Raspberry PI - 7" Touch TFT - Squeeze Play
MLD 6.5 - lirc yaUsbIR - 4 x DD-Sat - Intel N100M - 4GB RAM - 64GB SSD + 12TB HDD + 22TB HDD - Lian Li PC-C37B - Samsung LE40A559

Offline rell

  • Newbie
  • *
  • Posts: 4
    • View Profile
Entwicklungsumgebung 6.5
« Reply #16 on: February 17, 2026, 08:59:07 »
Hallo zusammen,

ich hatte ja tatsächlich schon einen Account :)

Ich habe mal begonnen, mir eine Entwicklungsumgebung aufzubauen. Allerdings scheitere ich daran, dass mein System wohl zu neu ist. Debian 13 auf RPi5. Keine Ahnung, wie lange der build auf dem RPI5 benötigen würde, jedenfalls scheitert es schon daran, dass kein python2.7 mehr verfügbar ist, was wohl für meta-firefox benötigt wird.
Außerdem ist mein rock pi 4b+ nicht im scarthgap branch enthalten und wurde erst im Oktober mit aufgenommen https://git.yoctoproject.org/meta-rockchip/commit/conf/machine/rock-pi-4b-plus.conf?id=df4a83d8a41124d69d8105b56680c543432cfb3e. Das könnte ich wohl lösen, wenn ich den manuell irgendwie hinzufüge?
Trotzdem bleibt das python2.7 Problem. Kann ich das irgendwie umgehen? Ein Debian 11 Sytem möchte ich nicht aufsetzen, auch nicht unbedingt eine parallele Python 2 Installation.

Danke und Gruß
Andreas
Logged

Offline clausmuus

  • Administrator
  • Expert Member
  • ********
  • Posts: 21280
    • View Profile
    • ClausMuus.de
Entwicklungsumgebung 6.5
« Reply #17 on: February 17, 2026, 12:19:00 »
Meines Wissens ist Python 2.7 Pflicht. Da wirst Du nicht drum hin kommen.
Wir bauen in einem Docker Container, um das Host System sauber zu halten.

Allerdings kommt ein RPI als Build Umgebung nur in Frage, wenn Du Dir für einen initialen kompletten Build eine Wochen oder mehr Zeit nehmen willst. Außerdem solltest Du nach Möglichkeit auf einer SSD Bauen. Eine Festplatte geht notfalls auch, ist aber deutlich langsamer. Ein Build auf einer SD-Karte oder gar auf einem USB Stick brauchst Du erst gar nicht versuchen. Die Würden das vermutlich nicht überleben, mal abgesehen von der Vervielfachung der benötigten Zeit.
Logged
MLD 5.5 - Raspberry PI - 7" Touch TFT - Squeeze Play
MLD 6.5 - lirc yaUsbIR - 4 x DD-Sat - Intel N100M - 4GB RAM - 64GB SSD + 12TB HDD + 22TB HDD - Lian Li PC-C37B - Samsung LE40A559

Offline gitano

  • Newbie
  • *
  • Posts: 11
    • View Profile
Entwicklungsumgebung 6.5
« Reply #18 on: February 17, 2026, 12:36:22 »
Moin,

so, hab dann graphtftng endlich mit bitbake zum Laufen gekriegt :)

Der Trick war letzenlich doch noch mal eine Blick in die letzten yavdr Pakete zu werfen und die Makefile patches zu übernehemen: -std=c++11 bei den CXXFlags did the trick -> keine Abhängigkeitsprobleme mehr, baut sauber durch:

Code: [Select]
SUMMARY = "GraphTFT plugin for VDR"
DESCRIPTION = "GraphTFT is a plugin for the Video Disc Recorder and shows information about the current state of VDR on sencodary displays."

PV = "git"
PACKAGE_ARCH = "${TUNE_PKGARCH}_extra"
LICENSE = "GPL-2.0-only"

SRCREV = "76a0802a6dd84c9c049a5492152f64761a66844d"
SRC_URI = "git://github.com/vdr-projects/vdr-plugin-graphtftng;protocol=https;branch=master"
SRC_URI[sha256sum] = "27654712d582fd2bea12d730e8d824bc82281617"

SRC_URI += " \
file://00_Makefile.patch \
file://remote.conf.graphtft-fe \
file://anthraize.theme \
file://DeepBlue.theme \ 
file://nOpacity.theme \ 
file://PearlHD.theme \   
"

S = "${WORKDIR}/git"

TARGET_CC_ARCH += "${LDFLAGS}"

inherit vdr-plugin

DEPENDS += "ffmpeg imlib2 libgtop glib-2.0 libexif"


do_install() {
oe_runmake DESTDIR=${D} install

         install -m 0644 -D ${WORKDIR}/remote.conf.graphtft-fe ${D}${sysconfdir}/vdr/remote.conf.graphtft-fe
install -m 0644 -D ${WORKDIR}/anthraize.theme ${D}${sysconfdir}/vdr/plugins/graphtftng/themes/anthraize.theme
install -m 0644 -D ${WORKDIR}/DeepBlue.theme ${D}${sysconfdir}/vdr/plugins/graphtftng/themes/DeepBlue.theme
install -m 0644 -D ${WORKDIR}/nOpacity.theme ${D}${sysconfdir}/vdr/plugins/graphtftng/themes/nOpacity.theme
install -m 0644 -D ${WORKDIR}/PearlHD.theme ${D}${sysconfdir}/vdr/plugins/graphtftng/themes/PearlHD.theme
         install -m 0755 -D ${S}/graphtft-fe/graphtft-fe ${D}${bindir}/graphtft-fe
}

Eine erste Version, installiert das plugin, graphtftng-fe, remote.conf.graphtft-fe und ein paar rudimentäre theme files. Letzteres ist noch nicht so schön, bastel grad an einem receipe für verschiedene themes die man dann nachinstallieren kann (versuch grad herauszufinden wie man bitbake davon überzeugen kann mehre dateien/ ordner rekursiv ein ein Installdir zu kopieren)

Ansonsten funktioniert das super, als reines Anzeigeplugin mit dem stock MLD VDR, wenn man allerdings mit VDR OSD in graphtftng navigieren will (imho DAS Killerfeature) braucht's den letzten patch aus dem git (liegt auch im receipe file Ordner, s. Anhang):

https://github.com/vdr-projects/vdr-plugin-graphtftng/blob/master/patch/vdr-2.7.5_graphtftng.diff

Hab den vdr-2.7.9 damit problemlos gebaut und alle plugins nochmal nachkompiliert -> funzt :)

Next step: graphlcd-base + plugin

@clausmuus: jo, mit einer udev Regel unter /etc/udev/rules.d/

Code: [Select]
KERNEL=="sr0", SYMLINK+="dvd", OPTIONS+="link_priority=-100"
läuft das dvd plugin astrein

Lieben Gruß,
gitano
« Last Edit: February 17, 2026, 12:39:00 by gitano »
Logged

Offline clausmuus

  • Administrator
  • Expert Member
  • ********
  • Posts: 21280
    • View Profile
    • ClausMuus.de
Entwicklungsumgebung 6.5
« Reply #19 on: February 17, 2026, 18:44:44 »
Hi,
die remote.conf.graphtft-fe muss nach /etc/vdr/remote.conf.d/graphtft-fe.conf installiert werden, damit die vom VDR verwendet wird.
Die Themes sollten möglichst nach /usr/share/vdr/plugins/graphtftng/themes/ installiert werden (${sharedir}/vdr/plugins/graphtftng/themes/). Damit das funktioniert muss entweder ein Aufruf Argument mit dem Pfad angegeben werden (schau Dir das ende des vdr-plugin-web bb Files für ein Beispiel an), oder ein Patch erstellt werden, der das in den Sourcen anpasst.

Es ist auch möglich mit einem bb File mehrere Pakete zu erstellen. Üblicherweise so was wie PAKETNAME-A, PAKETNAME-B. Eventuell ist das für Deine Themes interessant.
Logged
MLD 5.5 - Raspberry PI - 7" Touch TFT - Squeeze Play
MLD 6.5 - lirc yaUsbIR - 4 x DD-Sat - Intel N100M - 4GB RAM - 64GB SSD + 12TB HDD + 22TB HDD - Lian Li PC-C37B - Samsung LE40A559

Offline gitano

  • Newbie
  • *
  • Posts: 11
    • View Profile
Entwicklungsumgebung 6.5
« Reply #20 on: February 18, 2026, 21:33:31 »
Moin,

@clausmuus: Vielen Dank für die Hinweise -> habe ich angepasst! Hier das aktulle receipe:

Code: [Select]
SUMMARY = "GraphTFT plugin for VDR"
DESCRIPTION = "GraphTFT is a plugin for the Video Disc Recorder and shows information about the current state of VDR on sencodary displays."

PV = "git"
PACKAGE_ARCH = "${TUNE_PKGARCH}_extra"
LICENSE = "GPL-2.0-only"

SRCREV = "76a0802a6dd84c9c049a5492152f64761a66844d"
SRC_URI = "git://github.com/vdr-projects/vdr-plugin-graphtftng;protocol=https;branch=master"
SRC_URI[sha256sum] = "27654712d582fd2bea12d730e8d824bc82281617"

SRC_URI += " \
file://00_Makefile.patch \
file://remote.conf.graphtft-fe \
"

S = "${WORKDIR}/git"

TARGET_CC_ARCH += "${LDFLAGS}"

inherit vdr-plugin

DEPENDS += "ffmpeg imlib2 libgtop glib-2.0 libexif ttf-bitstream-vera"


do_install() {
oe_runmake DESTDIR=${D} install

         install -m 0644 -D ${WORKDIR}/remote.conf.graphtft-fe ${D}${sysconfdir}/vdr/remote.conf.d/remote.conf.graphtft-fe
         install -m 0755 -D ${S}/graphtft-fe/graphtft-fe ${D}${bindir}/graphtft-fe
}

pkg_postinst:${PN}() {
#!/bin/sh
         mkdir -p /etc/vdr/plugins/graphtftng
         mkdir -p /etc/vdr/plugins/graphtftng/themes
         touch /etc/vdr/plugins/graphtftng/themes/dummy.theme
         mkdir -p /etc/vdr/plugins/graphtftng/fonts
         ln -sf /usr/share/fonts/ttf/Vera.ttf /etc/vdr/plugins/graphtftng/fonts/Vera.ttf
         ln -sf /usr/share/fonts/ttf/VDRSymbolsSans.ttf /etc/vdr/plugins/graphtftng/fonts/VDRSymbolsSans.ttf
}

Bei den postinst routinen hab ich noch "touch /etc/vdr/plugins/graphtftng/themes/dummy.theme" drin -> ich plane die Themes separat in verschieden paketen zu erstellen, das dummy.theme soll nur verhindern das der vdr bei der graphtftng installation crasht. Kann ich dann auch damit verhindern in dem ich ein theme paket als Abhängigkeit mitgebe.

Zwei Dinge lassen mich noch grübeln:

1. graphtft-fe: Momentan lasse ich das plugin noch direkt über X11 die Infos ausgeben, ich könnte auch das graphtft-fe Programm verwenden als separater Anzeige daemon über X (so ähnlich wie surf mit osd2web) -> ist das vllt. besser weil sicherer so?

2. Der Task ein simples theme Paket zu bauen treibt mich die letzten Tage fast in den Wahnsinn x) zunächst hatte ich dann als Installationsroutine nach einigem hin- und her ein simples cp -r als tauglich befunden... dann fing er an rumzumeckern das die installierten Pakete sich nicht packetieren lassen, da nicht explizit im receipe erwähnt... ich liste die da aber ganz bestimmt nicht alle einzeln auf x) Ein "FILES:${PN} = "/vdr/plugins/graphtftng/themes/vdr-tftng-mango/*"" half dem Problem dann ab.

Nun baut er das Paket sauber durch....aber: aus irgendeinem Grund frisst bitbake die ${sharedir} variable in dem receipe nicht bei der Installation, er installert allns nach /vdr/plugins/graphtftng/themes

Code: [Select]
SUMMARY = "Anthraize Theme for VDR plugin graphtftng."
AUTHOR = "Andreas Grothe"
PV = "git"

PACKAGE_ARCH = "${TUNE_PKGARCH}_extra"
LICENSE = "GPL-2.0-only"
LIC_FILES_CHKSUM = "file://COPYRIGHT.txt;md5=9f867da7a73fad2715291348e80d0763"

SRC_URI = "git://github.com/lgitano/vdr-tftng-mango;protocol=https;branch=main"
SRCREV = "4aabfbe2d4642143c9b2196141a599eeb52a597d"

S = "${WORKDIR}/git"

FILES:${PN} = "/vdr/plugins/graphtftng/themes/vdr-tftng-mango/*"

do_install() {
install -d ${D}${sharedir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango
cp -r ${S}/* ${D}${sharedir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/
}

pkg_postinst:${PN}() {
#!/bin/sh
          ln -sf /usr/share/vdr/plugins/graphtftng/themes/vdr-tftng-mango /etc/vdr/plugins/graphtftng/themes/anthraize-mango
          ln -sf /usr/share/vdr/plugins/graphtftng/themes/vdr-tftng-mango/fonts/graphTFT.ttf /etc/vdr/plugins/graphtftng/fonts/graphTFT.ttf
}

Irgendwelche Ideen woran das liegen könnte?

Vielen Dank!

Lieben Gruß,
-gitano
Logged

Offline clausmuus

  • Administrator
  • Expert Member
  • ********
  • Posts: 21280
    • View Profile
    • ClausMuus.de
Entwicklungsumgebung 6.5
« Reply #21 on: February 19, 2026, 08:52:19 »
Hi,
erst mal nur ganz kurz, ausführlicher kommt später:
- die Zeile PACKAGE_ARCH = "${TUNE_PKGARCH}_extra" ist für andere arten von Paketen gedacht. Die muss raus.
- Alls was Du in pkg_postinst geschrieben hast, gehört in die do_install Funktion, natürlich leicht angepasst. Für das "mkdir ..." gibt es ein "install ..." äquivalent.
- Die remote install Zeile muss so lauten:
Code: [Select]
install -m 0644 -D ${WORKDIR}/remote.conf.graphtft-fe ${D}${sysconfdir}/vdr/remote.conf.d/graphtft-fe.conf- Die Variable ${sharedir} gibt es nur wenn Du ein inherit "vdr-plugin" gemacht hast. Ansonsten heißt die ${datadir}. Die ${datadir} Variable hatte ich erst entdeckt, als ich bereits ${sharedir} erstellt und in Plugins sehr oft verwendet hate. Das ${sharedir} bzw. ${datadir} muss auch in der FILES Zeile verwendet werden, kann aber nicht im postinst verwendet werden.
« Last Edit: February 19, 2026, 09:00:20 by clausmuus »
Logged
MLD 5.5 - Raspberry PI - 7" Touch TFT - Squeeze Play
MLD 6.5 - lirc yaUsbIR - 4 x DD-Sat - Intel N100M - 4GB RAM - 64GB SSD + 12TB HDD + 22TB HDD - Lian Li PC-C37B - Samsung LE40A559

Offline gitano

  • Newbie
  • *
  • Posts: 11
    • View Profile
Entwicklungsumgebung 6.5
« Reply #22 on: February 19, 2026, 12:16:38 »
Moin Claus,

ahhhh, danke Dir!

das theme Paket ist angepasst und löppt so weit:

Code: [Select]
SUMMARY = "Anthraize Theme for VDR plugin graphtftng."
AUTHOR = "Andreas Grothe"
PV = "git"

LICENSE = "GPL-2.0-only"
LIC_FILES_CHKSUM = "file://COPYRIGHT.txt;md5=9f867da7a73fad2715291348e80d0763"

PACKAGE_ARCH = "${TUNE_PKGARCH}_extra"

SRC_URI = "git://github.com/lgitano/vdr-tftng-mango;protocol=https;branch=main"
SRCREV = "4aabfbe2d4642143c9b2196141a599eeb52a597d"

S = "${WORKDIR}/git"

FILES:${PN} = " \
${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/* \
${sysconfdir}/vdr/plugins/graphtftng \
${sysconfdir}/vdr/plugins/graphtftng/* \
"

do_install() {
install -d ${D}${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango
install -d ${D}${sysconfdir}/vdr/plugins/graphtftng/themes
install -d ${D}${sysconfdir}/vdr/plugins/graphtftng/fonts
cp -r ${S}/* ${D}${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/
        ln -sf ${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/ ${D}${sysconfdir}/vdr/plugins/graphtftng/themes/anthraize-mango
        ln -sf ${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/fonts/graphTFT.ttf ${D}${sysconfdir}/vdr/plugins/graphtftng/fonts/graphTFT.ttf
}

Das PACKAGE_ARCH = "${TUNE_PKGARCH}_extra" hab ich grad noch drin, weil er das beim bauen nach core2-64_extra-mld-linux installiert -> das Verzeichniss ist immer so schön übersichtlich x) Kann ich aber gerne wieder rausnhemen, dann. Kann ich da dann auch defienieren ob ein Paket z.B. für arm Architekturen bauen kann?
Hab gestern nochmal an graphllcd-base weiter gebaut, das läuft mittlerweile schon gut durch, für 2 Treiber ssd1306 und ili341 braucht's die wiringpi library -> das ist definitv speziell für RPi Nutzer interessant, denk ich mal :) Einige x86 boards haben mittlerweile auch einen gpio header (hab eins hier), aber das ist eher selten.

Lieben Gruß,
-gitano
Logged

Offline gitano

  • Newbie
  • *
  • Posts: 11
    • View Profile
Entwicklungsumgebung 6.5
« Reply #23 on: February 19, 2026, 14:04:50 »
Jo, ich denke mal die kann man so nehmen, oder?

Code: [Select]
SUMMARY = "GraphTFT plugin for VDR"
DESCRIPTION = "GraphTFT is a plugin for the Video Disc Recorder and shows information about the current state of VDR on sencodary displays."
AUTHOR = "Jörg Wendel <vdr@jwendel.de>"

PV = "git"
LICENSE = "GPL-2.0-only"

SRCREV = "76a0802a6dd84c9c049a5492152f64761a66844d"
SRC_URI = "git://github.com/vdr-projects/vdr-plugin-graphtftng;protocol=https;branch=master"
SRC_URI[sha256sum] = "27654712d582fd2bea12d730e8d824bc82281617"

SRC_URI += " \
file://00_Makefile.patch \
file://remote.conf.graphtft-fe \
"

S = "${WORKDIR}/git"

TARGET_CC_ARCH += "${LDFLAGS}"

inherit vdr-plugin

DEPENDS += "ffmpeg imlib2 libgtop glib-2.0 libexif ttf-bitstream-vera vdr-tftng-mango"


do_install() {
oe_runmake DESTDIR=${D} install

         install -m 0644 -D ${WORKDIR}/remote.conf.graphtft-fe ${D}${sysconfdir}/vdr/remote.conf.d/graphtft-fe.conf
         install -m 0755 -D ${S}/graphtft-fe/graphtft-fe ${D}${bindir}/graphtft-fe
         install -d ${D}${sysconfdir}/vdr/plugins/graphtftng
install -d ${D}${sysconfdir}/vdr/plugins/graphtftng/themes
install -d ${D}${sysconfdir}/vdr/plugins/graphtftng/fonts
         ln -sf  ${datadir}/fonts/ttf/Vera.ttf ${D}${sysconfdir}/vdr/plugins/graphtftng/fonts/Vera.ttf
}

Code: [Select]
SUMMARY = "Anthraize Theme for VDR plugin graphtftng."
AUTHOR = "Andreas Grothe"
PV = "git"

LICENSE = "GPL-2.0-only"
LIC_FILES_CHKSUM = "file://COPYRIGHT.txt;md5=9f867da7a73fad2715291348e80d0763"

SRC_URI = "git://github.com/lgitano/vdr-tftng-mango;protocol=https;branch=main"
SRCREV = "4aabfbe2d4642143c9b2196141a599eeb52a597d"

S = "${WORKDIR}/git"

FILES:${PN} = " \
${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/* \
${sysconfdir}/vdr/plugins/graphtftng \
${sysconfdir}/vdr/plugins/graphtftng/* \
"

do_install() {
install -d ${D}${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango
install -d ${D}${sysconfdir}/vdr/plugins/graphtftng/themes
install -d ${D}${sysconfdir}/vdr/plugins/graphtftng/fonts
cp -r ${S}/* ${D}${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/
        ln -sf ${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/ ${D}${sysconfdir}/vdr/plugins/graphtftng/themes/anthraize-mango
        ln -sf ${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/fonts/graphTFT.ttf ${D}${sysconfdir}/vdr/plugins/graphtftng/fonts/graphTFT.ttf
}

Lieben Gruß,
-gitano
« Last Edit: February 19, 2026, 22:09:53 by gitano »
Logged

Online rfehr

  • MLD-Developer
  • Expert Member
  • ******
  • Posts: 1716
    • View Profile
Entwicklungsumgebung 6.5
« Reply #24 on: February 19, 2026, 23:28:53 »
Quote from: gitano on February 19, 2026, 14:04:50
Jo, ich denke mal die kann man so nehmen, oder?

Code: [Select]
SUMMARY = "GraphTFT plugin for VDR"
DESCRIPTION = "GraphTFT is a plugin for the Video Disc Recorder and shows information about the current state of VDR on sencodary displays."
AUTHOR = "Jörg Wendel <vdr@jwendel.de>"

PV = "git"
LICENSE = "GPL-2.0-only"

SRCREV = "76a0802a6dd84c9c049a5492152f64761a66844d"
SRC_URI = "git://github.com/vdr-projects/vdr-plugin-graphtftng;protocol=https;branch=master"
SRC_URI[sha256sum] = "27654712d582fd2bea12d730e8d824bc82281617"

SRC_URI += " \
file://00_Makefile.patch \
file://remote.conf.graphtft-fe \
"

S = "${WORKDIR}/git"

TARGET_CC_ARCH += "${LDFLAGS}"

inherit vdr-plugin

DEPENDS += "ffmpeg imlib2 libgtop glib-2.0 libexif ttf-bitstream-vera vdr-tftng-mango"


do_install() {
oe_runmake DESTDIR=${D} install

         install -m 0644 -D ${WORKDIR}/remote.conf.graphtft-fe ${D}${sysconfdir}/vdr/remote.conf.d/graphtft-fe.conf
         install -m 0755 -D ${S}/graphtft-fe/graphtft-fe ${D}${bindir}/graphtft-fe
         install -d ${D}${sysconfdir}/vdr/plugins/graphtftng
install -d ${D}${sysconfdir}/vdr/plugins/graphtftng/themes
install -d ${D}${sysconfdir}/vdr/plugins/graphtftng/fonts
         ln -sf  ${datadir}/fonts/ttf/Vera.ttf ${D}${sysconfdir}/vdr/plugins/graphtftng/fonts/Vera.ttf
}

Code: [Select]
SUMMARY = "Anthraize Theme for VDR plugin graphtftng."
AUTHOR = "Andreas Grothe"
PV = "git"

LICENSE = "GPL-2.0-only"
LIC_FILES_CHKSUM = "file://COPYRIGHT.txt;md5=9f867da7a73fad2715291348e80d0763"

SRC_URI = "git://github.com/lgitano/vdr-tftng-mango;protocol=https;branch=main"
SRCREV = "4aabfbe2d4642143c9b2196141a599eeb52a597d"

S = "${WORKDIR}/git"

FILES:${PN} = " \
${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/* \
${sysconfdir}/vdr/plugins/graphtftng \
${sysconfdir}/vdr/plugins/graphtftng/* \
"

do_install() {
install -d ${D}${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango
install -d ${D}${sysconfdir}/vdr/plugins/graphtftng/themes
install -d ${D}${sysconfdir}/vdr/plugins/graphtftng/fonts
cp -r ${S}/* ${D}${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/
        ln -sf ${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/ ${D}${sysconfdir}/vdr/plugins/graphtftng/themes/anthraize-mango
        ln -sf ${datadir}/vdr/plugins/graphtftng/themes/vdr-tftng-mango/fonts/graphTFT.ttf ${D}${sysconfdir}/vdr/plugins/graphtftng/fonts/graphTFT.ttf
}

Lieben Gruß,
-gitano

wenn die kompletten bb Pakete fertig sind, kannst du uns ja gerne zur verfügung stellen dann nehmen wir die gerne mt auf.

Gruß,
  Roland

P.S.: es sind ja nicht bur die bb Pakete, du hast ja auch noch Patches mit drin, die werden natürlich auch benötigt
Logged
1x OctopusNet 4x DVB-C
1x Zotac ITX-A Atom 330
1x RPI2 als Client
1x BananaPi
1x Wetekplay
1x MCC 100
2x RPI3
2x RPi4
1x RPI5
2x Zotac Mini

Offline clausmuus

  • Administrator
  • Expert Member
  • ********
  • Posts: 21280
    • View Profile
    • ClausMuus.de
Entwicklungsumgebung 6.5
« Reply #25 on: Today at 00:18:57 »
Mir ist noch etwas aufgefallen. Der Parameter "-D" beim "install" Aufruf wird verwendet wenn mehrere Dateien eines Ordners auf einmal kopiert werden sollen (funktioniert aber nicht rekursiv).
Du verwendest den beim installieren von graphtft-fe.conf und graphtft-fe. Da wird der nicht benötigt.
Schau mal in's bb File vom VDR für ein paar Beispiele.
« Last Edit: Today at 09:44:33 by clausmuus »
Logged
MLD 5.5 - Raspberry PI - 7" Touch TFT - Squeeze Play
MLD 6.5 - lirc yaUsbIR - 4 x DD-Sat - Intel N100M - 4GB RAM - 64GB SSD + 12TB HDD + 22TB HDD - Lian Li PC-C37B - Samsung LE40A559

1 [2] MLD-6.x / General / Entwicklungsumgebung 6.5
 



Users Online Users Online

0 Members and 1 Guest are viewing this topic.